Inductor Finders Power  |   RF
Datasheet Index
Check Price+Stock
Power Magnetics Tools
RF Inductor Tools
New! CM Choke Finder
New! LC Filter Designer
IC / Inductor Match Tool
Application Notes
Other Tools
Designer's Kits

BACK

Using Coilcraft's Advanced Models in LTSpice


Coilcraft’s power inductors are included the LTSpice inductor library

These simple inductor models are adequate for many simulations, such as low-frequency, well-below-resonance power supply simulations. When resonance and other higher-frequency effects and losses are to be simulated, these simple models will not provide the required detail and may lead to false conclusions.

More advanced inductor models available here.

Depending on the inductor series, the advanced SPICE models may include a variable inductor element, variable series resistance (Rvar1) to model skin effect, a resistor element in series with the parallel capacitance (R1) to limit impedance at resonance, and a variable parallel resistance (Rvar2) to model frequency-dependent low power core losses.

Advanced Power Inductor Model

The schematic, element values, and coefficients for variable elements are provided in the PSPICE model document for each inductor series.

The GLaplace component is used in SPICE to describe a frequency-dependent impedance or resistance. Each frequency-dependent element (Rvar1, Rvar2, Lvar) is modeled in LTSpice using the GLaplace (g or g2) component.

Instructions for Creating the Model Schematic in LTSpice

  • Place components for all fixed resistors and the capacitor.
  • Change the values to those shown on the Coilcraft SPICE model document for the inductor being modeled.
  • Place a Glaplace component for each variable resistor and inductor element (typically Rvar1, Rvar2, and Lvar).
  •  For each Gaplace component, copy and paste the corresponding Laplace statements below into the value field of the Glaplace element. (Be sure to rename L1 if multiple inductors are used).
For use LAPLACE=+1/{L1_K1}/(-S*S/4/PI^2)^0.25
For use LAPLACE=+1/{L1_K2}/(-S*S/4/PI^2)^0.25

For use LAPLACE=+1/(S*1e-6*({L1_K3}-({L1_K4}*LOG({L1_K5}*(S/(2*pi))))))

  • Next, use .param statement to define the K1 through K5 coefficients from the Coilcraft SPICE model document.
  • Connect the components per the SPICE document schematic.

Example Schematic and Netlist

The schematic below uses the Coilcraft LPS4018-332 as an example:

This is the corresponding netlist for the example schematic:

* Coilcraft LPS4018-332 3.3 uH Inductor Advanced Model
R2 INPUT1 N001 .11
C1 N001 N003 2.26pF
R1 N003 0 120
V1 INPUT1 0 AC 1
G1 N002 0 N002 0 LAPLACE=+1/(S*1e-6*({L1_K3} - ({L1_K4}*LOG({L1_K5}*(S/(2*pi))))))
G2 N001 N002 N001 N002 LAPLACE=+1/{L1_K1}/(-S*S/4/PI^2)^0.25
G3 N001 0 N001 0 LAPLACE=+1/{L1_K2}/(-S*S/4/PI^2)^0.25
.param L1_K5 = 9.8E-6
.param L1_K2 = 0.792
.param L1_K1 = 1.80E-4
.param L1_K3 = 3.3
.param L1_K4 = 0.083
* Coil Craft: LPS4018-332ML 3.3 uH
.ac dec 100 100K 100Meg
* NOTE: Ind = Im(V(n001)/I(R2))/(2*pi*frequency)
.backanno
.end

When running simulations, note the upper and lower frequency limits for which the model is valid. This information is shown on the Coilcraft SPICE model document for each inductor series.

To plot inductance vs. frequency, use the statement:
Im(V(n001)/I(R2))/(2*pi*frequency)

BACK